In some cases. If m divides n, then GF(2^n) can be constructed as an extension of GF(2^m), in which case there is a natural inclusion of GF(2^m) into GF(2^n).

I assume that by "polynomial function" and "mapping" you mean a homomorphism.

Also, any two finite fields of the same order are isomorphic, Combining that with above, we get a homomorphism from GF(2^m) to GF(2^n) if m divides n.

Alec

Lychrel:=proc(n)
    local s,m;
    uses StringTools;
    m:=n;
    s:=""||m;
    to 50 do
        m:=m+parse(Reverse(s));
        s:=""||m;
        if IsPalindrome(s) then return false fi 
    od;
    true
end;

time(nops(select(Lychrel,[$1..10000])));

                                0.577

Faster than 1 sec.

Alec

If there were 2 polynomials of degree 3 passing through those points, their difference would have 4 roots (at the x values at this points), which means that it is 0.

To consstruct 2 (or more) polynomials of degree 5 passing through them, you can start with any polynomial of degree 5, for example, with x^5 +x^4 and x^5 -x^4, evaluate them at the x values at this points, substract that from the y-values, and construct polynomials of degree 3 passing through those new points. Adding them to x^5+x^4, or whatever, will produce polynomials of degree  5 passing through the original points.

To construct a polynomial of deree 3 passing through them, CurvrFitting:-PolynomialInterpolation can be used.

Alec

complexplot is doing something different. You need plot.

The summation to 100 is good for R(x) with not very large x, but may be not good enough for non-trivial zeros, even with x=50. In general, the sum to infinity has to be used. It is very slow in Maple though.

Alec

The sum over trivial zeros is

-1/2 + arctan(ln(x)/Pi)/Pi

Alec

Just looked at the Project Euler problems related to palindromes. I looked briefly and saw only 2 of them (one is number 4). In both of them, conversion to strings and using StringTools:-IsPalindrome produces the answer with 1-line code well faster than in 1 sec.

No back conversion to numbers (i.e. parse) is required. Just seq, map and select.

What problems need more than 1 minute?.

Alec

The plot can be done using plot3d as

plot3d(`+`, -12 .. 12, -12 .. 12, style = point, 
    symbol = circle, axes = boxed, view = 1 .. 24, 
    color = red, orientation = [30, 75]);

Normally, with pointplot3d one first creates a list of points for plotting - in this example, something like

P:=select(x->x[3]>0,[seq(seq([i,j,i+j],i=-12..12),j=-12..12)]):

or

P:=[seq(seq(`if`(i+j>0,[i,j,i+j],NULL),i=-12..12),j=-12..12)]:

and then plots them,

plots:-pointplot3d(P, axes = boxed, symbol = circle, 
    color = red, orientation = [30, 75]);

Alec

This bug was discussed earlier.

Alec

I'm not sure if that works in Maple 11, but in Maple 12.02 both Mean and StandardDeviation work for lists, too, not only for Arrays,

L:=[1,2,3,4,5];

                         L := [1, 2, 3, 4, 5]

Statistics:-Mean(L);

                                  3.

Statistics:-StandardDeviation(L);

                             1.581138830

Statistics:-DataSummary(L);

  [mean = 3., standarddeviation = 1.581138830, skewness = 0.,

        kurtosis = 1.360000000, minimum = 1., maximum = 5.,

        cumulativeweight = 5.]

Alec

You can do that in text, but not in Maple input. Well, something like domain (but not exactly) can be specified, but codomain - no.

Something like that is possible to do in Axiom and Sage, but not in Maple.

I don't exactly understand why you need that. If you had a concrete example in mind and posted it here, then somebody could show how to do that Maple way.

Alec

In the first case, the limit at the discontinuity is undefined, it is infinity from the right, and -infinity from the left. In the second case, the function is positive, and the limit at the discontinuity is "infinity".

Alec

Here is another example,

with(Maplets:-Elements):
m:=Maplet([
    [TextField['a']('value'=3,10,halign=right), 
        Label("mod"), 
        TextField['p']('value'=5,10)],
    Button("Inverse",Evaluate('b'= '1/a mod p')),
    TextField['b'](10,halign=center)]):
Maplets:-Display(m);

Alec

Why not?

First, you have to plot the functions,

f:=10*ln(x):
g:=4-x^4-x:
plot([f,g],x=0.9..1.4);

Now, find the intersection points,

a:=solve(f);
                                a := 1
b:=fsolve(g,x=1..2);
                           b := 1.283781666
c:=fsolve(f=g);
                           c := 1.131110382

For future calculations, we will use f on the interval from a to c, and g on the interval from c to b, so we can add these intervals to their definitions,

f := f, x=a..c:
g := g, x=c..b:

First, the area under the curves,

int(f)+int(g);
                             0.1816593733

Second, the volume of revolution about the x axis,

V:=Student:-Calculus1:-VolumeOfRevolution:
V(f)+V(g);
                             0.4780945459

Third, the volume of revolution about x=4,

W:=rcurry(V, axis=vertical, distancefromaxis=4):
W(f)+W(g);
                             3.264832489

Alec

Student:-VectorCalculus also can be used. Here is an example of using PlotVector for plotting a list of vectors,

with(Student:-VectorCalculus):
PlotVector([<1, 0, 0>, <0, 1, 0>, <0, 0, 1>]);

Also, arrow options can be used to modify the plot. For example, something like

PlotVector([<1, 0, 0>, <0, 1, 0>, <0, 0, 1>],
    shape = double_arrow, head_length = 0.1);

PlotVector([<1, 0, 0>, <0, 1, 0>, <0, 0, 1>],
    shape = arrow, head_length = 0.05, head_width = 0.02, 
    color = black);

In many situations it may be convenient to use the plots:-arrow command directly instead of PlotVector.

Alec

See also the animation on the Matthew R. Watkins's page.

Alec